Get previous value(s) of SP multiple selection columns in Power Automate

“The previously described solution works fine, but Power Automate returns an error on a multiple selection columns, how can I process them too?”

Some time ago I wrote a blog post on using Power Automate to get the previous values of updated SP columns. However, that solution works only for single selection columns. Once there’s a multiple choice, lookup or people picker column, the solution will end with an error message. The expressions expect a value, but multiple choice fields provide an array. This post is an extension of the previous one in case your SharePoint list has such columns.

Why it doesn’t work

The problem was already explained in previous posts on exporting the multiple choice or multiple people picker columns to csv. If it’s a multiple selection column, it contains an array. And as such you can’t access the values directly. You must somehow deal also with the array. Either take a specific object from the array and its value, or a specific values for each of them. And the latter is what you want to do for the multiple choice columns.

How to recognise multiple selection columns

As described in the post on processing JSON, arrays can be recognised by brackets [ and ]. If the object contains the brackets, it’s an array. And this is a knowledge you can use also in this solution. The old expressions looked for a specific words defining the field type, e.g. FieldLookupValue or SPListExpandedUser.

The same approach can be used also to check if given field type contains an array. If it contains ‘FieldLookupValue’ and ‘[‘ at the same time, it’s a multiple lookup field. If it contains ‘SPListExpandedUser’ and ‘[‘ it’s a multiple people picker. And once you know it’s a multiple selection field, you can process it accordingly. For the old values:

if(contains(string(outputs('Compose')),'FieldLookupValue'),
  if(contains(string(outputs('Compose')),'['),
    <multiple selection lookup>,
    outputs('Compose')?['LookupValue'] = <single selection lookup>
  ),
  if(contains(string(outputs('Compose')),'FieldUserValue'),
    if(contains(string(outputs('Compose')),'['),
        <multiple selection people picker>,
        outputs('Compose')?['LookupValue'] = <single selection people picker>
    ),
    if(contains(string(outputs('Compose')),'String'),
        <multiple selection choice>,
        outputs('Compose') = <all other column types>
    )
  )
)

And for the new values:

if(contains(string(outputs('Compose_2')),'SPListExpandedReference'),
  if(contains(string(outputs('Compose_2')),'['),
    <multiple selection lookup or choice field>,
    outputs('Compose_2')?['Value'] = <single selection lookup>
  ),
  if(contains(string(outputs('Compose_2')),'SPListExpandedUser'),
    if(contains(string(outputs('Compose')),'['),
        <multiple selection people picker>,
        outputs('Compose_2')?['DisplayName'] = <single selection people picker>
    ),
    outputs('Compose_2') = <all other column types>
  )
)

What is missing are the expressions for the multiple selection columns.

Multiple selection choice columns

Multiple choice column is the first one, and the easiest one.

To get the original values just convert the [‘results’] array to a string.

join(outputs('Compose')?['Results'],', ')

The updated values can be then extracted with the xpath(…) expression. It’s the same expression that will be used also for the multiple lookup column values.

join(xpath(xml(json(concat('{"body":{"value":', outputs('Compose_2') , '}}'))), '/body/value/Value/text()'), ', ')

Adding them to the expressions:

if(contains(string(outputs('Compose')),'FieldLookupValue'),
  if(contains(string(outputs('Compose')),'['),
    <multiple selection lookup>,
    outputs('Compose')?['LookupValue']
  ),
  if(contains(string(outputs('Compose')),'FieldUserValue'),
    if(contains(string(outputs('Compose')),'['),
        <multiple selection people picker>,
        outputs('Compose')?['LookupValue']
    ),
    if(contains(string(outputs('Compose')),'String'),
        join(outputs('Compose')?['Results'],', '),
        outputs('Compose')
    )
  )
)

if(contains(string(outputs('Compose_2')),'SPListExpandedReference'),
  if(contains(string(outputs('Compose_2')),'['),
    join(xpath(xml(json(concat('{"body":{"value":', outputs('Compose_2') , '}}'))), '/body/value/Value/text()'), ', '),
    outputs('Compose_2')?['Value']
  ),
  if(contains(string(outputs('Compose_2')),'SPListExpandedUser'),
    if(contains(string(outputs('Compose')),'['),
        <multiple selection people picker>,
        outputs('Compose_2')?['DisplayName']
    ),
    outputs('Compose_2')
  )
)

Multiple selection people picker columns

The multiple people picker columns are provided as objects in both situations, therefore, you must use the xpath(…) expression for both.

if(contains(string(outputs('Compose')),'FieldLookupValue'),
  if(contains(string(outputs('Compose')),'['),
    <multiple selection lookup>,
    outputs('Compose')?['LookupValue']
  ),
  if(contains(string(outputs('Compose')),'FieldUserValue'),
    if(contains(string(outputs('Compose')),'['),
        join(xpath(xml(json(concat('{"body":{"value":', outputs('Compose') , '}}'))), '/body/value/results/LookupValue/text()'), ', '),
        outputs('Compose')?['LookupValue']
    ),
    if(contains(string(outputs('Compose')),'String'),
        join(outputs('Compose')?['Results'],', '),
        outputs('Compose')
    )
  )
)

if(contains(string(outputs('Compose_2')),'SPListExpandedReference'),
  if(contains(string(outputs('Compose_2')),'['),
    join(xpath(xml(json(concat('{"body":{"value":', outputs('Compose_2') , '}}'))), '/body/value/Value/text()'), ', '),
    outputs('Compose_2')?['Value']
  ),
  if(contains(string(outputs('Compose_2')),'SPListExpandedUser'),
    if(contains(string(outputs('Compose')),'['),
        join(xpath(xml(json(concat('{"body":{"value":', outputs('Compose_2') , '}}'))), '/body/value/DisplayName/text()'), ', '),
        outputs('Compose_2')?['DisplayName']
    ),
    outputs('Compose_2')
  )
)

Multiple selection lookup columns

As already mentioned above, multiple selection lookup columns are the same as multiple choice columns for the current values. That means, the second expression is already complete, all that’s left is to extract the old values in the first one.

if(contains(string(outputs('Compose')),'FieldLookupValue'),
  if(contains(string(outputs('Compose')),'['),
    join(xpath(xml(json(concat('{"body":{"value":', outputs('Compose') , '}}'))), '/body/value/results/LookupValue/text()'), ', '),
    outputs('Compose')?['LookupValue']
  ),
  if(contains(string(outputs('Compose')),'FieldUserValue'),
    if(contains(string(outputs('Compose')),'['),
        join(xpath(xml(json(concat('{"body":{"value":', outputs('Compose') , '}}'))), '/body/value/results/LookupValue/text()'), ', '),
        outputs('Compose')?['LookupValue']
    ),
    if(contains(string(outputs('Compose')),'String'),
        join(outputs('Compose')?['Results'],', '),
        outputs('Compose')
    )
  )
)

if(contains(string(outputs('Compose_2')),'SPListExpandedReference'),
  if(contains(string(outputs('Compose_2')),'['),
    join(xpath(xml(json(concat('{"body":{"value":', outputs('Compose_2') , '}}'))), '/body/value/Value/text()'), ', '),
    outputs('Compose_2')?['Value']
  ),
  if(contains(string(outputs('Compose_2')),'SPListExpandedUser'),
    if(contains(string(outputs('Compose')),'['),
        join(xpath(xml(json(concat('{"body":{"value":', outputs('Compose_2') , '}}'))), '/body/value/DisplayName/text()'), ', '),
        outputs('Compose_2')?['DisplayName']
    ),
    outputs('Compose_2')
  )
)

Summary

As you can see, extracting the previous and current values from multiple selection SP columns with Power Automate is not easy. It makes the solution that was quite complex before even more complicated. But if your list contains these multiple selection columns, you don’t have much of a choice. It’s either removing them, or adjusting the flow. And I suppose the second option is the preferred one.